writeSol.F90

Go to the documentation of this file.

 
subroutine writesol(famList, nFamList)
    !
    !       writeSol controls the writing of a new grid file, a volume
    !       solution file and a surface solution file.
    !
    use constants
    use extraoutput
    use communication, only: adflow_comm_world
    use monitor, only: writevolume
    use inputio, only: storerindlayer
    use killsignals, only: localsignal, globalsignal
    use flowvarrefstate, only: nw
    use outputmod, only: sethelpvariableswriting, &
                         releasehelpvariableswriting, gridfilenames, volsolfilenames, &
                         surfsolfilenames
    use writecgnsgrid, only: writecgnsgridfile
    use writecgnsvolume, only: writecgnsvolumesol
    use writecgnssurface, only: writecgnssurfacesol
    use utils, only: terminate, deallocatetempmemory, allocatetempmemory
    use haloexchange, only: reshalo1
    implicit none
 
    integer(kind=intType), intent(in) :: nFamList
    integer(kind=intType), dimension(nFamList), intent(in) :: famList
    !
    !      Local variables.
    !
    integer :: ierr
 
    integer(kind=intType) :: i, nn
 
    ! If residuals must be written to the volume solution and if halo
    ! values must be stored, exchange the data here, because in the
    ! next call the communication buffers are deleted.
 
    if (writevolume .and. storerindlayer .and. &
        (volwriteresrho .or. volwriteresmom .or. &
         volwriteresrhoe .or. volwriteresturb)) &
        call reshalo1(1_inttype, 1_inttype, nw)
 
    ! Temporary deallocate some memory, such that writeSolution
    ! is not a memory killer.
 
    call deallocatetempmemory(.true.)
 
    ! Write the files. The routines called depend on the IO
    ! format used.
 
    call sethelpvariableswriting
    call writecgnsgridfile
    call writecgnsvolumesol
    call writecgnssurfacesol(famlist)
    call releasehelpvariableswriting
 
    ! Release the memory of the file names.
 
    deallocate (gridfilenames, volsolfilenames, &
                surfsolfilenames, stat=ierr)
    if (ierr /= 0) &
        call terminate("writeSol", &
                       "Deallocation failure for the file names.")
 
    ! Allocate the memory again that was deallocated in the beginning
    ! of this routine.
 
    call allocatetempmemory(.true.)
 
#ifndef USE_NO_SIGNALS
 
    ! It is possible that a kill signal was sent during the writing.
    ! Therefore determine the global signal as the maximum of the
    ! local ones.
 
    call mpi_allreduce(localsignal, globalsignal, 1, adflow_integer, &
                       mpi_max, adflow_comm_world, ierr)
#endif
 
end subroutine writesol