signals.F90

Go to the documentation of this file.

  subroutine set_signal_write
      !
      !       set_signal_write sets the localSignal to signalWrite. On the
      !       finest mesh this means that after the current iteration a
      !       solution is written. On the coarser grids this signal will be
      !       ignored.
      !       This routine is only compiled when signalling is supported.
      !
#ifndef USE_NO_SIGNALS
 
      use constants
      use communication, only: myid
      use inputphysics, only: equationmode
      use killsignals, only: localsignal, nosignal, signalwrite
      use iteration, only: groundlevel
      use commonformats, only: strings
      implicit none
      !
      !      Local variables.
      !
      character(len=7) :: integerString
 
      ! The user signals must be reconnected again, because the
      ! connection is lost after a signal has been given.
 
      call connect_signals
 
      ! Parallel executable.  Write a general message that this
      ! processor has received a write signal.
 
      write (integerstring, '(i7)') myid
      integerstring = adjustl(integerstring)
      integerstring = trim(integerstring)
      print "(a)", "#"
      print strings, "# Processor ", integerstring(:len_trim(integerstring)), ": Received write signal."
 
      ! Check if a signal was set previously.
 
      testprevious: if (localsignal /= nosignal) then
 
          ! A signal was set before. Set it back to noSignal
          ! and write a message that this has been done.
 
          localsignal = nosignal
 
          print "(a)", "# Signal was set previously and will now be overwritten to no signal"
 
          else testprevious
 
          ! No signal was set yet.
          ! Determine the situation and act accordingly.
 
          if (groundlevel == 1) then
 
              ! Finest grid. A solution file will be written after either
              ! this multigrid cycle or this time step. This depends whether
              ! this is a steady or an unsteady computation.
              ! In both cases localSignal must be set to signalWrite.
 
              localsignal = signalwrite
 
              select case (equationmode)
 
              case (steady, timespectral)
                  print "(a)", "# Solution will be written after this iteration"
 
              case (unsteady)
                  print "(a)", "# Solution will be written after this time step"
              end select
 
          else
 
              ! Coarser grid. Signal information will be ignored.
 
              print "(a)", "# Solver is still on a coarse grid and therefore the signal is ignored."
              print "(a)", "# Use kill -USR2 if you want to go to the next finer grid level."
 
          end if
 
      end if testprevious
 
      ! Write a blank line, such that the message is pretty clear.
 
      print "(a)", "#"
 
#endif /* USE_NO_SIGNALS */
 
  end subroutine set_signal_write
 
  !      ==================================================================
 
  subroutine set_signal_write_quit
      !
      !       set_signal_write_quit sets the localSignal to
      !       signalWriteQuit. On the finest mesh this means that after
      !       the current iteration the solution is written and the
      !       computation is stopped. On the coarser grids the solution is
      !       transferred to the next finer level and the computation is
      !       continued there.
      !       This routine is only compiled when signalling is supported.
      !
#ifndef USE_NO_SIGNALS
 
      use constants
      use communication, only: myid
      use inputphysics, only: equationmode
      use killsignals, only: localsignal, nosignal, signalwritequit
      use iteration, only: groundlevel
      use commonformats, only: strings
      implicit none
      !
      !      Local variables.
      !
      character(len=7) :: integerString
 
      ! The user signals must be reconnected again, because the
      ! connection is lost after a signal has been given.
      ! Only when signalling is wanted.
 
      call connect_signals
 
      ! Parallel executable. Write a general message that this
      ! processor has received a write and quit signal.
 
      write (integerstring, '(i7)') myid
      integerstring = adjustl(integerstring)
      integerstring = trim(integerstring)
      print "(a)", "#"
      print strings, "# Processor ", integerstring(:len_trim(integerstring)), ": Received write and quit signal."
 
      ! Check if a signal was set previously.
 
      testprevious: if (localsignal /= nosignal) then
 
          ! A signal was set before. Set it back to noSignal
          ! and write a message that this has been done.
 
          localsignal = nosignal
 
          print "(a)", "# Signal was set previously and will now be overwritten to no signal"
 
          else testprevious
 
          ! Set localSignal to signalWriteQuit.
 
          localsignal = signalwritequit
 
          ! Determine the situation and act accordingly.
 
          if (groundlevel == 1) then
 
              ! Finest grid. A solution file will be written and the
              ! computation stopped after either this multigrid cycle or
              ! this time step. This depends whether this is a steady or an
              ! unsteady computation.
 
              select case (equationmode)
              case (steady, timespectral)
                  print "(a)", "# Solution will be written and computation stopped after this multigrid cycle"
 
              case (unsteady)
                  print "(a)", "# Solution will be written and computation stopped after this time step"
              end select
 
          else
 
              ! Coarser grid. The solution is transferred to the next finer
              ! grid level. This happens either after this multigrid cycle
              ! or after this time step depending on whether this is a
              ! steady or an unsteady computation.
 
              print "(a)", "# Solver is still on the coarse grid."
 
              select case (equationmode)
              case (steady, timespectral)
                  print "(a)", "# Solution will be transferred to the next finer grid after this multigrid cycle."
 
              case (unsteady)
                  print "(a)", "# Solution will be transferred to the next finer grid after this time step."
              end select
 
          end if
 
      end if testprevious
 
      ! Write a blank line, such that the message is pretty clear.
 
      print "(a)", "#"
 
#endif /* USE_NO_SIGNALS */
 
  end subroutine set_signal_write_quit