surfaceFamilies.F90

Go to the documentation of this file.

module surfacefamilies
 
    use constants
#ifndef USE_TAPENADE
#include <petsc/finclude/petsc.h>
    use petsc
    implicit none
 
    type familyexchange
        ! Vectors for global traction calc
 
        ! Parallel vector of un-uniqufied values concatenated for all
        ! included surfaces
        vec nodevallocal
 
        ! Parallel vector of uniqueifed values.
        vec nodevalglobal
 
        ! Sum global. Same size as nodeValGlobal
        vec sumglobal
 
        ! Scatter from nodeValLocal to NodeValGlobal
        vecscatter scatter
 
        ! Flag for allocated petsc variables
        logical :: allocated = .false.
        integer(kind=intType), dimension(:), allocatable :: famlist
 
        integer(Kind=intType) :: sps
        integer(kind=intType) :: nnodes
    end type familyexchange
 
    type bcgrouptype
        integer(kind=intType), pointer, dimension(:) :: famlist
    end type bcgrouptype
 
    ! Generic PETSc scatters
    is is1, is2
 
    ! The list of exchanges based on boundary condition type
    type(familyexchange), dimension(:, :), allocatable, target :: bcfamexchange
 
    ! List of familis grouped by BC. See constants.F90 for the indices
    ! to use for this array.
    type(bcgrouptype), dimension(nFamExchange) :: bcfamgroups
 
    ! The full list of the family names
    character(len=maxCGNSNameLen), dimension(:), allocatable :: famnames
 
    ! List of all families. This is just 1,2,3,4...nFam. It is just used
    ! in fortran when a specific family is not required.
    integer(kind=intType), dimension(:), allocatable :: fullfamlist
#endif
 
    ! Special BC array's that are sometime required for reducitons.
    real(kind=realtype), dimension(:, :), allocatable, target :: zerocellval
    real(kind=realtype), dimension(:, :), allocatable, target :: onecellval
    real(kind=realtype), dimension(:, :), allocatable, target :: zeronodeval
 
#ifndef USE_TAPENADE
contains
 
    subroutine getnfam(nfam)
 
        implicit none
        integer(kind=inttype), intent(out) :: nfam
        if (allocated(famnames)) then
            nfam = size(famnames)
        else
            nfam = 0
        end if
 
    end subroutine getnfam
 
    subroutine getfam(i, fam)
        implicit none
        character(len=maxCGNSNameLen), intent(out) :: fam
        integer(kind=intType), intent(in) :: i
 
        if (allocated(famnames)) then
            fam = famnames(i)
        end if
 
    end subroutine getfam
 
    subroutine destroyfamilyexchange(exch)
 
        use constants
        type(familyexchange) :: exch
        integer(kind=intType) :: ierr
        if (exch%allocated) then
 
            call vecdestroy(exch%nodeValLocal, ierr)
            call vecdestroy(exch%nodeValGlobal, ierr)
            call vecdestroy(exch%sumGlobal, ierr)
            call vecscatterdestroy(exch%scatter, ierr)
 
        end if
 
        exch%allocated = .false.
 
    end subroutine destroyfamilyexchange
#endif
end module surfacefamilies